Adafruit NFC for arduino – tutorial

In questi giorni sono venuto in possesso di un Adafruit NFC shield per arduino da utilizzare per un progetto su commissione ed ho eseguito qualche test prima di impegnarla in un progetto complesso.

L’Adafruit NFC è una shield basata sul PN532 in grado di leggere sia i tag di tipo NFC sia RFID a 13.56MHz.

In passato hai letto dei miei test con una shield simile della DF Robot: NFC Arduino in cui avevo testato la mia shield NFC prodotta dalla DF Robot.

Come funziona l’Adafruit NFC

L’adafruit NFC shield comunica con arduino mediante il protocollo I2C come scritto sul sito del produttore: I2C 7-bit address 0x48 ossia usa l’indirizzo 0x48 i2C e la shield é completamente compatibile con l’arduino uno attraverso il classico montaggio a castello.

La shield è pre-assemblata al 90% mancano i solo header che vengono forniti come semplici pin maschi e che puoi sostituire con i classici header passanti a cui sei abituato per le altre shield.

Le istruzioni di montaggio le puoi trovare in questo link.

Se desideri approfondire il funzionamento dei tag NFC puoi leggere questa pagina presente sul sito adafruit stesso.

Ho provato la shield adafruit nfc con una tessera ATM ( Azienda Trasporti Milanesi ) di quelle anonime che puoi acquistare e ricaricare presso le edicole:

per la lettura ho usato uno degli sketch di esempio forniti dall’adafruit con la libreria per il controllo dell’PN532.

Sketch di test

Lo sketch che ho utilizzato per il test è il “readMifare” che ti riporto:

/**************************************************************************/
/*! 
    @file     readMifare.pde
    @author   Adafruit Industries
    @license  BSD (see license.txt)

    This example will wait for any ISO14443A card or tag, and
    depending on the size of the UID will attempt to read from it.
   
    If the card has a 4-byte UID it is probably a Mifare
    Classic card, and the following steps are taken:
   
    - Authenticate block 4 (the first block of Sector 1) using
      the default KEYA of 0XFF 0XFF 0XFF 0XFF 0XFF 0XFF
    - If authentication succeeds, we can then read any of the
      4 blocks in that sector (though only block 4 is read here)
   
    If the card has a 7-byte UID it is probably a Mifare
    Ultralight card, and the 4 byte pages can be read directly.
    Page 4 is read by default since this is the first 'general-
    purpose' page on the tags.


    This is an example sketch for the Adafruit PN532 NFC/RFID 
    breakout boards
    This library works with the Adafruit NFC breakout 
      ----> https://www.adafruit.com/products/364
 
    Check out the links above for our tutorials and wiring diagrams 
    These chips use I2C to communicate

    Adafruit invests time and resources providing this open source code, 
    please support Adafruit and open-source hardware by purchasing 
    products from Adafruit!
*/
/**************************************************************************/
#include <Wire.h>
#include <Adafruit_NFCShield_I2C.h>

#define IRQ   (2)
#define RESET (3)  // Not connected by default on the NFC Shield

Adafruit_NFCShield_I2C nfc(IRQ, RESET);

void setup(void) {
  Serial.begin(115200);
  Serial.println("Hello!");

  nfc.begin();

  uint32_t versiondata = nfc.getFirmwareVersion();
  if (! versiondata) {
    Serial.print("Didn't find PN53x board");
    while (1); // halt
  }
  // Got ok data, print it out!
  Serial.print("Found chip PN5");
  Serial.println((versiondata>>24) & 0xFF, HEX); 
  Serial.print("Firmware ver. ");
  Serial.print((versiondata>>16) & 0xFF, DEC); 
  Serial.print('.'); Serial.println((versiondata>>8) & 0xFF, DEC);
  
  // configure board to read RFID tags
  nfc.SAMConfig();
  
  Serial.println("Waiting for an ISO14443A Card ...");
}


void loop(void) {
  uint8_t success;
  uint8_t uid[] = { 0, 0, 0, 0, 0, 0, 0 };  // Buffer to store the 
                                            // returned UID
  uint8_t uidLength;                        // Length of the UID 
                                            // (4 or 7 bytes depending 
                                            // on ISO14443A card type)
    
  // Wait for an ISO14443A type cards (Mifare, etc.).  When one is found
  // 'uid' will be populated with the UID, and uidLength will indicate
  // if the uid is 4 bytes (Mifare Classic) or 7 bytes (Mifare Ultralight)
  success=nfc.readPassiveTargetID(PN532_MIFARE_ISO14443A,uid,&uidLength);
  
  if (success) {
    // Display some basic information about the card
    Serial.println("Found an ISO14443A card");
    Serial.print("  UID Length: ");
    Serial.print(uidLength, DEC);
    Serial.println(" bytes");
    Serial.print("  UID Value: ");
    nfc.PrintHex(uid, uidLength);
    Serial.println("");
    
    if (uidLength == 4)
    {
      // We probably have a Mifare Classic card ... 
      Serial.println("Seems to be a Mifare Classic card (4 byte UID)");
    
      // Now we need to try to authenticate it for read/write access
      // Try with the factory default KeyA: 0xFF 0xFF 0xFF 0xFF 0xFF 0xFF
      Serial.print("Trying to authenticate block 4");
      Serial.println(" with default KEYA value");
      uint8_t keya[6] = { 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF };
    
      // Start with block 4 (the first block of sector 1) since sector 0
      // contains the manufacturer data and it's probably better just
      // to leave it alone unless you know what you're doing
      success=nfc.mifareclassic_AuthenticateBlock(uid,uidLength,4,0,keya);
    
      if (success)
      {
        Serial.println("Sector 1 (Blocks 4..7) has been authenticated");
        uint8_t data[16];
    
        // If you want to write something to block 4 to test with, uncomment
        // the following line and this text should be read back in a minute
        // memcpy(data, (const uint8_t[]){ 'a', 'd', 'a', 'f', 'r', 'u',
        // 'i', 't', '.', 'c', 'o', 'm', 0, 0, 0, 0 }, sizeof data);
        // success = nfc.mifareclassic_WriteDataBlock (4, data);

        // Try to read the contents of block 4
        success = nfc.mifareclassic_ReadDataBlock(4, data);
    
        if (success)
        {
          // Data seems to have been read ... spit it out
          Serial.println("Reading Block 4:");
          nfc.PrintHexChar(data, 16);
          Serial.println("");
      
          // Wait a bit before reading the card again
          delay(1000);
        }
        else
        {
          Serial.print("Ooops ... unable to read the requested block.");
          Serial.println("  Try another key?");
        }
      }
      else
      {
        Serial.println("Ooops ... authentication failed: Try another key?");
      }
    }
    
    if (uidLength == 7)
    {
      // We probably have a Mifare Ultralight card ...
      Serial.println("Seems to be a Mifare Ultralight tag (7 byte UID)");
    
      // Try to read the first general-purpose user page (#4)
      Serial.println("Reading page 4");
      uint8_t data[32];
      success = nfc.mifareultralight_ReadPage (4, data);
      if (success)
      {
        // Data seems to have been read ... spit it out
        nfc.PrintHexChar(data, 4);
        Serial.println("");
    
        // Wait a bit before reading the card again
        delay(1000);
      }
      else
      {
        Serial.println("Ooops ... unable to read the requested page!?");
      }
    }
  }
}

non entro nel dettagli della descrizione in quanto il codice è semplice e ben commentato e la documentazione fornita dalla adafruit è alquanto soddisfacente, tuttavia se ti occorrono delle delucidazioni su questo sketch puoi usare i commenti per chiedermele e proverò a rispondere alle domande.

Il risultato sul mio monitor seriale è stato il seguente:

l’adafruit nfc è riuscita a riconoscere la tessera ATM che gli ho avvicinato ma non è riuscita ad eseguire l’autenticazione in quanto il codice prova ad autenticarsi con la sequenza di byte standard per le Mifare non protette ed ovviamente la tessera che ho utilizzato non usa un codice di accesso standard.

Questa l’adafruit nfc accesa e pronta alla lettura dei tag nfc che vorrai testare:

Buon divertimento