Andamento del servo con Arduino

pilotare un servo con Arduino lo hai già imparato in alcuni dei miei precedenti articoli, ti mostro il risultato di alcuni esperimenti condotti sul controllo dell’andamento del servo, esperimenti condotti in collaborazione con Federico C., amico, appassionato di innovazione e tecnologia.

Hai già avuto modo di vedere alcuni dei progetti nati dalla mente di Federico e dalla nostra collaborazione:

• Robot sfera presentato a Roma in occasione dell’Arduino Day 2012;
• Umanoide lo studio delle matematiche che potrebbero consentire ad un robot di simulare la camminata umana;
• Mano biomeccanica lo studio 3D di una mano riproducibile con una stampante 3D tipo RepRap;

Gli ultimi due progetti hanno ispirato questo articolo e descrizione degli studi eseguiti.

Controllare l’andamento del servo con Arduino

Il progetto parte da una premessa che ti invito a testare con un

Esercizio: apri e chiudi un dito e osserva la velocità che assume all’inizio, al momento di massima estensione e poco prima di completare la chiusura, avrai notato che non è costante ossia non si sposta sempre a velocità ed accellerazione uniforme.

Osservazione: da quanto hai osservato hai dedotto che l’andamento del servo a cui colleghi il dito della tua mano non può far variare il proprio andamento in modo costante ma dovrà avere un andamento più lento in partenza la cui velocità aumenta progressivamente per rallentare in prossimità del della massima estensione in cui inverte il verso di rotazione ed ricomincia ad aumentare fino a metà della chiusura per rallentare e fermarsi quando il dito è chiuso.

Il fenomeno che hai osservato ed ho provato a descriverti è un andamento del servo di tipo sinusoidale:

per ottenerlo devi sconfinare nel mondo della trigonometria, ecco a cosa serve la trigonometria, a parte gli scherzi quella che stai per applicare è trigonometria applicata ala robotica.

Lo scopo di gestire l’andamento del servo

a cosa serve tutto questo ragionamento?

a parte ad aver trovato un’applicazione della trigonometria in robotica, lo scopo vero è poter programmare un robot perché i suoi movimenti siano più naturali possibili, stiamo parlando di Umanoidi.

Per calcolare la sinusoide che renda il controllo dell’andamento del servo tale da permettere un movimento abbastanza veritiero puoi utilizzare alla funzione sin( X ) in cui X è l’angolo variabile.

Il vantaggio è che la funzione sin( X ) al variare di X° restituisce un valore compreso tra -1 ed 1 ( trigonometria ) per cui la velocità con cui ambia X ti consente di definire velocità del movimento ed intervallo di accelerazione e decelerazione in prossimità dei cambi di andamento sinusoidale.

Il servo che ho utilizzato per i miei esperimenti lo hai già visto in tanti altri:

Le formule per pilotare l’andamento del servo

il solo valore di sin( X ) non è sufficiente ad essere utilizzato per controllare l’andamento del servo, in quanto il risultato varia tra -1 ed 1 ed otterresti un sevo che cambia da 0 a 1° perchè il grado -1 non è in grado di eseguirlo.

Il primo passo è calcolare il valore dell’angolo da inviare al servo.

Sai che un servo, normalmente, può ruotare da 0° a 180° e per sicurezza io evito di utilizzare gli estremi, almeno che non ne abbia bisogno, per cui considera l’escursione 10-170°.

Il punto centrale ossia quello della massima estensione del dito sarà (170-10)/2 = 160/2 = 80; puoi scrivere la formula come:

grado = (sin( X ) *80);

in cui al variare di sin( X ) da -1 a 1 otterrai un grado che varia da -80 a +80 gradi.

Sai che il servo non può riprodurre gradi inferiori a 0 ed inoltre che vorrei evitare di arrivare a 0° rimanendo a 10° per cui puoi sommare 90 al valore ottenuto e scrivere la formula come:

grado = (( sin(X) * 80 ) + 90 );

la cui variazione sarà 10° ….. 170° proprio quella che volevi ottenere per regolare l’andamento del servo.

Ho messo in un excel questa formula incrementando il valore di X di 0,5° ad ogni loop:

leggendo i valori ti sarai reso conto che l’ultima colonna passa da 90 a 170 a 10 gradi con un andamento che excel stesso mostra come:

ho fatto anche test con valori differenti di incremento per rendere la variazione dell’andamento del servo più o meno veloce, ottenendo variazioni della sinusoide in frequenza, trovi un’utile spiegazione dei fenomeni che interessano l’andamento della sinusoide su wikipedia.

Lo sketch

per complicarti un po la vita ho realizzato uno sketch in cui la variazione dell’incremento di X è regolata da un potenziometro, al variare del valore letto sulpin analogico A5 ( 0-1023 ) fai variare il valore moltiplicatore da 0 a 8:

#include <Servo.h>

#define pinServo 3
#define rad2grad 57.295779513

float angolo = 0;
double sen   = 0;
float grado  = 0;
int pinPot   = A5;

Servo servoA;

void setup() {
  Serial.begin( 9600 );
  Serial.println( " ------------------ Avvio ------------------------" );

  pinMode( pinPot, INPUT );
  digitalWrite( pinPot, LOW );

  servoA.attach( pinServo );
  servoA.write( grado );
}

void loop() {

  int pot = ( analogRead( pinPot ) / 127 );

  Serial.print( "Potenziometro: " );
  Serial.print( pot );

  Serial.print( "angoloK: " );
  Serial.print( angolo );

  sen = sin( (angolo/rad2grad) );

  Serial.print( " sin(K): " );
  Serial.print( sen );

  grado = (( sen * 80 ) + 90 );

  Serial.print( " grado: " );
  Serial.println( grado );

  servoA.write( grado );

  angolo = (angolo + pot );
}

lo sketch è semplice, se hai bisogno di chiarimenti sul funzionamento commenta l’articolo.

Tuttavia voglio fare una precisazione all’uso della funzione sin(X) in quanto X deve essere specificato in radianti e non in gradi, per cui devi convertire gradi in radianti prima di passarli alla funzione sin().

La costante di conversione è:

57.295779513

che imposti alla linea 04 come rad2grad;

linea 26: rimappi il valore letto su A5 nel fattore di incremnto da 0 a 8, infatti 1023 /127 = 8…. arrotondato ad 8 essendo pot una variabile integer ( intero );

linea 34: calcoli il valore dell’angolo da gradi in radianti dividendo i gradi per la costante di conversione;

linea 46: ricalcoli il valore dell’angolo ( in gradi ) sommando il valore precedente con il valore calcolato alla linea 26.

Il video dell’andamento del servo

Per darti meglio l’idea di cosa significa tutto questo ho realizzato il seguente video:

in cui vedi che il valore di moltiplicazione passa da 0 a 8 mentre io ruoto il potenziometro con un momento di pausa quando il fattore di incremento vale 4.

Buon lavoro !!!