Fingerprint Scanner TTL GT-511C3

Leggere le impronte digitali è possibile con il sensore Fingerprint Scanner TTL GT-511C3 distribuito dalla Sparkfun

Il sensore permette di  leggere e memorizzare fino a 200 impronte digitali e permette il riconoscimento ed il confronto fra un’impronta letta e quelle memorizzate nel suo database il tutto grazie ad una memoria interna e ad un processore che processa i dati in arrivo dal sensore. Arduino (o altri device collegati) non deve preoccuparsi di fare altro che di inviare (tramite comunicazione UART) i comandi al sensore ed attendere le risposte.

Il protocollo di comunicazione è spiegato esaurientemente nella pagina di sparkfun ma per poter aggirare l’ostacolo di sviluppare l’interfaccia di comunicazione, puoi scaricare una libreria già pronta all’uso.

Per le istruzioni su come aggiungere una libreria custom devi fare riferimento alla documentazione ufficiale Arduino.

Collegamento del Fingerprint Scanner TTL GT-511C3

Iniziamo a vedere come deve essere effettuato il collegamento elettrico ai pin Arduino.

Dal sensore escono 4 cavi. Due di questi devi collegarli a GND e all’alimentazione (io l’ho collegato al 5V ma le specifiche del sensore dicono che l’alimentazione può essere compresa fra 3.3 e 6V quindi dovrebbe essere possibile usare anche l’alimentazione 3.3V della scheda o il Vin se Arduino è alimentato con 6V o meno) mentre gli altri 2 devi collegarli a 2 pin digitali liberi di Arduino secondo il seguente schema:

Una volta capito come collegare il sensore ad Arduino capiamo la logica con cui lavora.

Come funziona il sensore fingerprint scanner

Il sensore ha 200 slot utilizzabili, ognuno, per memorizzare un’impronta digitale.

Per farlo devi completare una procedura di enrollment che consiste:

• nel far leggere al sensore 3 volte l’impronta dello stesso dito;
• fargli creare quello che viene definito template dell’impronta;
• memorizzare il template in uno dei suddetti slot per futuri confronti.

Attenzione: ogni slot può contenere un’unica impronta e non ci possono essere 2 slot con la stessa impronta, il sensore restituisce errore in questo caso.

Una volta memorizzate una o più impronte, puoi tentare un riconoscimento utilizzando l’apposito comando del Fingerprint Scanner TTL GT-511C3.

Lo Sketch di enrollment

Vediamo come funziona l’enrollment con uno sketch di esempio scritto utilizzando la libreria di cui sopra:

#include "FPS_GT511C3.h"
#include "SoftwareSerial.h" // usata dalla FPS_GT511C3.h

FPS_GT511C3 fps(12, 13);

void setup()
{
  Serial.begin(9600);
  delay(100);
  fps.Open();
  fps.SetLED(true);

}

void Enroll(int enrollid)
{
  int risultato;

  fps.EnrollStart(enrollid);
  Serial.print("Premi il dito #");
  Serial.print(enrollid);
  Serial.println(" sul sensore");
  while(fps.IsPressFinger() == false) delay(100);
  fps.CaptureFinger(true);
  Serial.println("Togli il dito");
  fps.Enroll1(); 
  while(fps.IsPressFinger() == true) delay(100);
  Serial.println("Premi nuovamente lo stesso dito");
  while(fps.IsPressFinger() == false) delay(100);
  fps.CaptureFinger(true);
  Serial.println("Rimuovi il dito");
  fps.Enroll2();
  while(fps.IsPressFinger() == true) delay(100);
  Serial.println("Premi lo stesso dito per l'ultima volta");
  while(fps.IsPressFinger() == false) delay(100);
  fps.CaptureFinger(true);
  Serial.println("Remove finger");
  risultato = fps.Enroll3();
  if (risultato== 0)
  {
    Serial.println("Enrolling OK");
  }
  else
  {
    Serial.print("Enroll fallito con codice d'errore:");
    Serial.println(risultato);
  }
}

void loop()
{
  for (int i=0;i<200;i++)
  {
    Enroll(i);
    delay(2000); 
  }
  fps.SetLED(false);
}

Analizziamo lo sketch nelle parti essenziali:

Riga 4: creazione dell’oggetto (C++) sensore. Si utilizza la funzione di libreria custom per creare l’oggetto sensore passandogli come parametri i pin digitali rx e tx (nell’ordine) a cui è collegato il sensore. Nel mio caso pin 12 e 13.

Riga 10: inizializza il sensore fingerprint scanner ttl gt-511C3.

Riga 11: accende la luce del sensore, necessaria per poter leggere le impronte.

Riga 19: funzione di libreria che fa partire la procedura di enrollment sullo slot passato come parametro.

Riga 23: controlla se sul sensore è poggiato un dito tramite la funzione di libreria isPressFinger che restituisce false se non c’è un dito true se il dito è presente. Questa riga attende finché il dito non viene posto sul sensore.

Riga 24: accertato che il dito è sul sensore la funzione CaptureFinger legge l’impronta e la valorizza nella RAM del sensore. Il parametro utilizzato può valere true si vuole una qualità maggiore (cattura più lenta) o false se si vuole una qualità minore (cattura più veloce). In rete si suggerisce di usare true per l’enrollment e false per il riconoscimento ma la differenza temporale è così bassa che io utilizzo sempre true.

Riga 26: primo step di enrollment sullo slot identificato dal parametro della funzione EnrollStart (riga20).

Riga 27: controlla che il dito sia stato rimosso altrimenti aspetta finché non viene rimosso.

Riga 30: Procede alla seconda cattura.

Riga 32: procede al secondo step dell’enrollment.

Riga 36: terza cattura.

Riga 38: Terzo e ultimo step dell’enrollment. Se il valore restituito è 0 il processo è andato a buon fine altrimenti si è verificato un errore.

Righe 50-58: Loop. Cerca di valorizzare un’impronta su ogni slot disponibile. Ovviamente si può interrompere la procedura quando si vuole staccando il cavo USB

Questo sketch è molto semplificato, utilizza solo alcuni dei comandi disponibili e non fa praticamente alcun controllo degli errori.

Per esempio non gestisce l’errore impronta duplicata quando si cerca di inserire la stessa impronta in 2 slot diversi.

Nell’articolo relativo al progetto completo vedrai come introdurre una complessità maggiore.

Riassumendo per memorizzare una nuova impronta

• devi scegliere uno slot libero
• far partire una procedura di enrollment ( specificando l’id dello slot utilizzando la funzione EnrollStart )
• devi poi catturare la prima impronta del dito con la funzione CaptureFinger
• avviare il primo step di enrollment con la funzione Enroll1
• catturare una seconda immagine
• far partire il secondo step con Enroll2
• catturare una terza immagine
• far partire il terzo ed ultimo step con la funzione Enroll3.

Di seguito una breve panoramica delle funzioni di libreria utilizzabili con Arduino.

Ci sono altri comandi (acquisizione dell’immagine letta dal sensore, trasmissione del tempalte per uso locale, ecc.) che non hanno senso di essere su Arduino.

Ti rimando quindi alla documentazione ufficiale della Sparkfun sul sensore Fingerprint Scanner TTL GT-511C3 se sei interessato.

Nel prossimo articolo vedremo come effettuare un riconoscimento una volta memorizzate alcune impronte.

void Open ():   inizializza il lettore

bool SetLED(bool on): accende o spegne la luce del lettore a seconda del valore passato: true accende, false spegne. Ritorna true se l’operazione ha avuto successo, false altrimenti.

int GetEnrollCount(): restituisce il numero di dita registrate.

bool CheckEnrolled(int id): restituisce true se lo slot id (da 0 a 199) è occupato altrimenti false.

int EnrollStart(int id): inizia il processo di cattura dell’impronta per lo slot id (da 0 a 199). Restituisce: 0 se OK, 1se database full, 2 se posizione non valida, 3 se slot id già occupato

int Enroll1(): prima scansione per il dito identificato dall’enrollstart precedente. Restituisce: 0 se OK, 1 o 2 se errore, 3 se impronta già presente

int Enroll2(): seconda scansione per il dito identificato dall’enrollstart precedente. Restituisce: 0 se OK, 1 o 2 se errore, 3 se impronta già presente

int Enroll3(): terza scansione per il dito identificato dall’enrollstart precedente con merge e salvataggio del template. Restituisce: 0 su OK, 1 o 2 se errore, 3 se impronta già presente

bool IsPressFinger(): controlla se un dito sta premendo sul sensore. Restituisce true se trova il dito, false altrimenti.

bool DeleteID(int id): cancella il template nella posizione id (e la libera). Restituisce false in caso di errore.

bool DeleteAll(): cancella tutti gli slot. Restituisce false se il DB è vuoto.

bool CaptureFinger (bool high_quality): cattura l’impronta del dito sul sensore e la memorizza nella memoria del sensore stesso. Andrà poi confrontata con il DB per individuare l’id. Restituisce true se la cattura ha successo, false se il sensore è vuoto.

int Verify1_1(int id): verifica se l’impronta catturata con la funzione CaptureFinger corrisponde all’impronta memorizzata nello slot identificato da id (da 0 a 199). Ritorna: 0 se corrispondono, 1 se la posizione non è valida (id < 0 o id > 199), 2 se l’id non in uso (vuoto), 3 se l’impronta non corrisponde a quella nello slot id

int Identify1_N (): restituisce l’id dello slot contenente l’impronta che corrisponde al dito catturata dalla funzione CaptureFinger. Se non la trova restituisce 200.